Flash style du texte tooltip question

// Tooltips plugin
 
var id:String="Tootips";
var version:String="1.0";
var panoController:Object=null;
var pano:Object=null;
var hotspots:Object;
var waitTimer:Timer;
 
// this function is called on plugin's start
function init (panoMain:Object) {
   panoController = panoMain;
   if (panoMain.addExternal(this)) {
      waitTimer = new Timer(50);
      waitTimer.addEventListener(TimerEvent.TIMER, waitHotspots, false, 0, true);
      waitTimer.start();
   }     
}
 
// this function is called when new panorama is loading
function newPano(link:Object) {
   pano = link;
}
 
// wait for Hotspots plugin to load before starting tooltips
function waitHotspots (event:Event) {
   if (panoController.externals.hotspots!=null) {
      waitTimer.stop();
      waitTimer = null
      hotspots = panoController.externals.hotspots;
      hotspots.addEventListener(MouseEvent.MOUSE_OVER, doOver, false, 0, true);
      hotspots.addEventListener(MouseEvent.MOUSE_OUT, doOut, false, 0, true);
      hotspots.addEventListener(MouseEvent.CLICK, doOut, false, 0, true);
   }
}
 
var animationTimer:Timer;
var speed:Number;
var currentObject:Object;
var alphaMax:Number = 1;
var alphaMin:Number = -1.4;
var alphaPlus:Number = 0.2;
var alphaMinus:Number = -0.08;
 
visible = false;
alpha = alphaMin;
tip.scale9Grid = new Rectangle(5, 5, tip.width-10, tip.height-10);
tip_txt.autoSize = TextFieldAutoSize.LEFT;
 
function doOver (event:Event) {
   // find object with property "attributes" (all hotspots has this object)
   var obj:Object = event.target;
   while (!obj.hasOwnProperty("attributes")) {
      if (obj.hasOwnProperty("parent")) {
         obj = obj.parent;
      } else {
         return;
      }
   }
   // try to get propery alt (stored in XML: <spot url="1.jpg" alt="My Picture" />)
   var text:String = obj.attributes.getParam("alt");
   if (text!=null) {
      currentObject = obj;
      // if text contais \n, it is multilines
      if (text.indexOf("\n")!=-1) {
         text = text.replace(/\n/g, "\n")
      }
      tip_txt.text = text;
      tip.width = tip_txt.width+10;
      tip.height = tip_txt.height+4;
      // start animation
      speed = alphaPlus;
      visible = true;
      if (animationTimer!=null) {
         animationTimer.stop();
      }
      animationTimer = new Timer(30);
      animationTimer.addEventListener(TimerEvent.TIMER, animation, false, 0, true);
      animationTimer.start();
   }
}
 
function doOut (event:Event) {
   speed = alphaMinus;
}
 
function animation (event:Event) {
   if (speed>0) {
      if (alpha < alphaMax) {
         alpha += speed;
      } else {
         alpha = alphaMax;
      }
      x = parent.mouseX-8;
      y = parent.mouseY+20;
      //
      if (x<0) {
         x = 0;
      }
      if (x+width>pano.width) {
         x = pano.width-width;
      }
      if (y+height>pano.height) {
         y = pano.height-height;
      }
      if (!currentObject.visible) {
         speed = alphaMinus;
      }
   } else {
      if (alpha > alphaMin) {
         alpha += speed;
      } else {
         alpha = alphaMin;
         animationTimer.stop();
         animationTimer = null;
      }
   }
}
 
function remove () {
   hotspots.removeEventListener(MouseEvent.MOUSE_OVER, doOver);
   hotspots.removeEventListener(MouseEvent.MOUSE_OUT, doOut);
   if (animationTimer!=null) {
      animationTimer.stop();
   }
   animationTimer = null;
}